pact - 30

(
s.waitForBoot{
Pdef.clear;
c= TempoClock(90/60);
Pdef(\sista).play(c, quant:8);
Pdef(\puh).play(c, quant:8);
Pdef(\hh).play(c, quant:8);
Pdef(\hh2).play(c, quant:8);
Pdef(\sn).play(c, quant:8);
Pdef(\sn2).play(c, quant:8);
}
)

(
Pdef(\sista, Pbind(
\instrument, \redMond,
\dur, Pseq([Pn(4, 4), Pseq([4, 2], 4), Pseq([4, 2, 2], 4), Pn(2, 4)], inf),
\amp, 0.4,
\legato, Pseq([Pn(0.08, 4), Pseq([0.08, 0.22], 4), Pseq([0.08, 0.22, 0.22], 4), Pn(0.22, 4)], inf),
\degree, 0,
\octave, Pstutter(4, Pseq([2, 3], inf)),
\rel, Pseq([Pn(0.1, 4), Pseq([0.1, 0.5], 4), Pseq([0.1, 0.5, 0.5], 4), Pn(0.5, 4)], inf),
\det, 0.9,
\sel, 0,
\sel2, 1,
\sel3, 2,
\selFreq, 10,
\selFreq2, 20,
\selFreq3, 30,
\amp2, 20,
\freq2, 2,
\amp3, 30,
\freq3, 3
));
)

(
Pdef(\puh, Pbind(
\instrument, \redMond,
\dur, Pseq([0.25, 3.75], inf),
\degree, Pseq([0, 5, 1, 4, 2, 3, 4, 1, 5, 0, \rest, \rest, 5, 4, 3, 2], inf),
\amp, Pseq([Pseq([0.07, 0.1], 5), 0, 0, 0.02, 0.03, 0.02, 0.03], inf),
\octave, 5,
\legato, 0.2,
\rel, 2.5,
\det, 0.9,
\sel, 3,
\selFreq, Pkey(\degree)+1,
\verbMix, 0,
\verbRoom, Pseq([Pseries(1, -0.05, 10), Pseries(0, 0.05, 10)], inf),
\ringMix, Pseq([Pseries(-1, 0.05, 20), Pseries(0, -0.05, 20)], inf),
\ringFreq, Pkey(\freq)
));
)

(
Pdef(\hh, Pbind(
\instrument, \redMond,
\dur, Pseq([Pseq([0.27, 0.23], 15), Pn(0.125, 4)], inf),
\degree, Pseq([-1, 0], inf),
\amp, Pseq([0.07, 0.1], inf)*0.2,
\octave, 5,
\legato, Pseq([Pseries(0.08, 0.005, 16)], inf),
\pan, Pseq([-0.15, 0.15], inf),
\atk, 0.01,
\rel, 0.01,
\det, 0.9,
\amp2, Pseq([Pseries(20, 1, 2000), Pseries(2020, -1, 2000)], inf),
\freq2, 200,
\distMix, Pseq([Pn(0, 60), 0.5, 0.75, 0.5, 0.25], inf)
));

Pdef(\hh2, Pbind(
\instrument, \redMond,
\dur, Pseq([Pseq([0.127, 0.123], 16), 16], inf),
\degree, Pseq([-1, 0], inf),
\amp, Pseq([0.07, 0.1], inf)*0.12,
\octave, 6,
\legato, Pseq([Pseries(0.08, 0.005, 16)], inf),
\pan, Pseq([-0.2, 0.2], inf),
\atk, 0.01,
\rel, 0.01,
\det, 0.9,
\amp2, Pseq([Pseries(30, 2, 1500), Pseries(3030, -2, 1500)], inf),
\freq2, 300,
\distMix, -0.9
));

Pdef(\sn, Pbind(
\instrument, \redMond,
\dur, 0.5,
\degree, 0,
\amp, Pseq([Pseq([0, 1], 16), Pseq([0.25, 1], 16), Pseq([0.5, 1], 16)], inf)*0.03,
\octave, 4,
\legato, 0.1,
\pan, 0.1,
\atk, 0.01,
\rel, 0.1,
\amp2, 400,
\freq2, 400,
\distMix, 0,
\moogMix, Pstutter(8, Pseq([1, 0.75, 0.5, 0.25, 0, 0.25, 0.5, 0.75, 1], inf))
));

Pdef(\sn2, Pbind(
\instrument, \redMond,
\dur, 4,
\degree, 0,
\amp, 0.02,
\octave, 5,
\legato, 0.1,
\pan, 0.1,
\atk, 0.01,
\rel, 3,
\amp2, 800,
\freq2, 800,
\distMix, Pseq([1, 0.75, 0.5, 0.25, 0, 0.25, 0.5, 0.75], inf),
\moogMix, 0.5
));

)

Pdef(\sista).stop
Pdef(\puh).stop
Pdef(\hh).stop
Pdef(\hh2).stop
Pdef(\sn).stop
Pdef(\sn2).stop